.版本 2
.支持库 spec
.程序集 窗口程序集_启动窗口
.子程序 __启动窗口_创建完毕
.子程序 _按钮1_被单击
.局部变量 条形码奇数编码, 文本型, , "0"
.局部变量 条形码偶数编码, 文本型, , "0"
.局部变量 条形码右边编码, 文本型, , "0"
.局部变量 条形码奇偶表, 文本型, , "0"
.局部变量 临时, 整数型, , , 用于计次
.局部变量 条形码字节集, 字节集
.局部变量 奇偶字节集, 字节集
.局部变量 二进制文本, 文本型
.局部变量 条码二进制, 字节集
' -------------------------------------------------------------------------------------[条形码编码]
条形码奇数编码 = { “0001101”, “0011001”, “0010011”, “0111101”, “0100011”, “0110001”, “0101111”, “0111011”, “0110111”, “0001011” }
' 标注 0 1 2 3 4 5 6 7 8 9
条形码偶数编码 = { “0100111”, “0110011”, “0011011”, “0100001”, “0011101”, “0111001”, “0000101”, “0010001”, “0001001”, “0010111” }
' 标注 0 1 2 3 4 5 6 7 8 9
条形码右边编码 = { “1110010”, “1100110”, “1101100”, “1000010”, “1011100”, “1001110”, “1010000”, “1000100”, “1001000”, “1110100” }
' 标注 0 1 2 3 4 5 6 7 8 9
条形码奇偶表 = { “000000”, “001011”, “001101”, “001110”, “010011”, “011001”, “011100”, “010101”, “010110”, “011010” }
' 标注 0 1 2 3 4 5 6 7 8 9
' -------------------------------------------------------------------------------------[初始化]
条形码字节集 = 到字节集 (编辑框1.内容)
.如果真 (取字节集长度 (条形码字节集) ≠ 13)
信息框 (“不够字数”, 0, , )
返回 ()
.如果真结束
' -------------------------------------------------------------------------------------[生成条形码]
二进制文本 = “202”
奇偶字节集 = 到字节集 (条形码奇偶表 [条形码字节集 [1] - 47])
.计次循环首 (12, 临时)
.判断开始 (临时 < 7)
.如果 (奇偶字节集 [临时] = 49) ' 文本"1"
二进制文本 = 二进制文本 + 条形码偶数编码 [条形码字节集 [临时 + 1] - 47]
.否则
二进制文本 = 二进制文本 + 条形码奇数编码 [条形码字节集 [临时 + 1] - 47]
.如果结束
.默认
二进制文本 = 二进制文本 + 条形码右边编码 [条形码字节集 [临时 + 1] - 47]
.判断结束
.如果真 (临时 = 6)
二进制文本 = 二进制文本 + “02020”
.如果真结束
.计次循环尾 ()
二进制文本 = 二进制文本 + “202”
调试输出 (二进制文本)
条码二进制 = 到字节集 (二进制文本)
' -------------------------------------------------------------------------------------[绘画条形码]
画板1.清除 (, , , )
.计次循环首 (取字节集长度 (条码二进制), 临时)
.如果真 (条码二进制 [临时] = 49) ' 文本"1"
画板1.画直线 (临时 + 5, 5, 临时 + 5, 55)
.如果真结束
.如果真 (条码二进制 [临时] = 50) ' 文本"2"
画板1.画直线 (临时 + 5, 5, 临时 + 5, 62)
.如果真结束
.计次循环尾 ()
' -------------------------------------------------------------------------------------[绘画数字]
画板1.定位写出 (0, 55, 字符 (条形码字节集 [1]))
.计次循环首 (6, 临时)
画板1.定位写出 (临时 × 7 + 3, 55, 字符 (条形码字节集 [临时 + 1]))
.计次循环尾 ()
.计次循环首 (6, 临时)
画板1.定位写出 (临时 × 7 + 50, 55, 字符 (条形码字节集 [临时 + 7]))
.计次循环尾 ()
易语言条码生成器
易语言回溯法
易语言条码 校验
易语言生成条形码
条形码0001101
易语言怎样记录一个条码包含其它条码
易语言怎么生条码